Sub HTTPDownload(indirizzo, percorso_locale)

    Dim i, objFile, objFSO, objHTTP, strFile, strMsg
    Const ForReading=1, ForWriting=2, ForAppending=8

    Set objFSO = CreateObject("Scripting.FileSystemObject")

    ' Controlla l'esistenza della cartella o del file di destinazione
    ' e crea il percorso completo per il file di destinazione
    If objFSO.FolderExists(percorso_locale) Then
        strFile = objFSO.BuildPath(percorso_locale, Mid(indirizzo, InStrRev(indirizzo, "/") + 1))
    ElseIf objFSO.FolderExists(Left(percorso_locale, InStrRev(percorso_locale, "\")- 1)) Then
        strFile = percorso_locale
    Else
        WScript.Echo "Errore: cartella di destinazione non trovata."
        Exit Sub
    End If

    ' Crea o apri il file di destinazione
    Set objFile = objFSO.OpenTextFile(strFile, ForWriting, True)

    ' Inizializza il download dei dati dal server remoto
    Set objHTTP = CreateObject("WinHttp.WinHttpRequest.5.1")
    objHTTP.Open "GET", indirizzo, False
    objHTTP.Send

    ' Scrivi i dati scaricati nel file di destinazione
    For i = 1 To LenB(objHTTP.ResponseBody)
        objFile.Write Chr(AscB(MidB(objHTTP.ResponseBody, i, 1)))
    Next

    objFile.Close()
End Sub

Dim dir_locale, result, i
Dim URL
Dim start_number, end_number
Dim l_end_number
Set WshShell = WScript.CreateObject("WScript.Shell")
dir_locale = WshShell.CurrentDirectory

result = InputBox("Inserire URL"& vbcrlf &"Digitare ?? come segnaposto per i numeri.", "Inserire URL", "http://")
If result = "" Then
	WScript.Echo "Operazione annullata."
	WScript.Quit
Else 
	URL=result
End If

result = InputBox("Da numero", "Da numero", "")
If result = "" Then
	WScript.Echo "Operazione annullata."
	WScript.Quit
Else 
	start_number=result
End If

result = InputBox("A numero", "A numero", "")
If result = "" Then
	WScript.Echo "Operazione annullata."
	WScript.Quit
Else 
	end_number=result
End If

l_end_number=len(cstr(end_number))
For i=start_number to end_number
	HTTPDownload replace(URL,"??", right("0000" & i , l_end_number)), dir_locale
Next

WScript.Echo "Operazione completata."
WScript.Quit