' Script realizzato da Michele Nasi - IlSoftware.it
' www.ilsoftware.it

' estrae la lettera identificativa dell'unitā dal quale lo script č eseguito:
Set fso = WScript.CreateObject ("Scripting.FileSystemObject")
strCurrentDrive = left(fso.GetAbsolutePathName("."),2)
 
' prepara l'esecuzione del comando "usbitcmd l":
Set objShell = CreateObject("WScript.Shell")
strCommand = "usbitcmd l"
Set objExecObject = objShell.Exec(strCommand)
 
Do While Not objExecObject.StdOut.AtEndOfStream
    ' legge ciascuna riga dell'output del comando "usbitcmd l":
    strResult = objExecObject.StdOut.ReadLine()
     
    ' estrae l'id corrispondente all'unitā dal quale lo script č eseguito (variabile deviceid):
    if instr(strResult,strCurrentDrive)>0 then
        pospipe=instr(strResult,"|")
 deviceid=trim(mid(strResult,1,pospipe-1))
    end if
Loop

nomefile=InputBox("Benvenuti nello strumento di backup dell'unitā USB "& strCurrentDrive &"."&vbcrlf&vbcrlf& _
	"Indicare il nome dell'archivio di backup da creare sul disco fisso:"&vbcrlf,"Backup USB","backupusb")
if nomefile="" then
	Set objShell = Nothing
	Set objExecObject = Nothing
	Msgbox "Backup annullato"
	WScript.Quit
end if

backup_file = "%userprofile%\Documenti\"&nomefile&"_"& deviceid &".imz"
messaggio = "Verrā effettuato il backup dell'unitā "& strCurrentDrive &"."&vbcrlf& _
        "Non rimuovere tale supporto sino alla comparsa del messaggio ""Backup completato""."& vbcrlf & vbcrlf & _
        "Il file di backup verrā salvato nel seguente percorso:"& vbcrlf & backup_file & vbcrlf & vbcrlf & _
        "Si desidera veramente procedere con il backup?"
Return = MsgBox(messaggio,4,"Attenzione")
if Return=6 then
    ' esegue il backup del contenuto dell'unitā usb:
    strCommand = "usbitcmd b "& deviceid &" "& backup_file &" /c"
 Return = objShell.Run (strCommand,0,true)
 
    WScript.Echo "Backup completato"
end if
 
Set objShell = Nothing
Set objExecObject = Nothing